'Copyright (C) 2007 Daniele Iunco

'This program is free software; you can redistribute it and/or modify
'it under the terms of the GNU General Public License as published by
'the Free Software Foundation; either version 2 of the License, or
'(at your option) any later version.

'This program is distributed in the hope that it will be useful,
'but WITHOUT ANY WARRANTY; without even the implied warranty of
'MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
'GNU General Public License for more details.

'You should have received a copy of the GNU General Public License along
'with this program; if not, write to the Free Software Foundation, Inc.,
'51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.

Imports System
Imports System.Configuration
Imports System.Web
Imports System.Reflection

Namespace GiDiNet

    'ManualBandwidthManagement v1.0
    'Author: Daniele Iunco
    'Date: 7th May 2007
    Public Class ManualBandwidthManagement
        Implements IHttpHandler

        Private Shared _Settings As BandwidthSettings
        Private Shared ReadOnly Property Settings() As BandwidthSettings
            Get
                If _Settings Is Nothing Then _Settings = New BandwidthSettings()
                Return _Settings
            End Get
        End Property

        Private Sub ProcessInvalidRequest(ByRef Context As HttpContext)
            'TODO: Qui si potrebbe sviluppare un sistema per notificare gli errori all'amministratore
            Context.Response.Redirect(Settings.MissingPageURL)
        End Sub

        Public Sub ProcessRequest(ByVal Context As HttpContext) Implements System.Web.IHttpHandler.ProcessRequest
            Dim myRequestPath As String = Context.Request.Path.ToLower()

            'Prelevo la configurazione della directory richiesta, se non la trovo restituisco la pagina di errore
            Dim myDirectory As String = Settings.GetDirectory(myRequestPath)
            If myDirectory Is Nothing Then
                'Se non ho trovato una directory restituisco la pagina di errore
                ProcessInvalidRequest(Context)
                Exit Sub
            End If

            'Questo primo controllo serve per evitare di eseguire troppe verifiche inutili: 
            'Se l'estensione più corta è di 3 caratteri e aggiungo 7 caratteri, la lunghezza del percorso richiesto deve essere per forza maggiore di 10 caratteri (la richiesta è nella forma "/percorso/a.ext.aspx")
            If myRequestPath.Length < myDirectory.Length + 10 Then
                ProcessInvalidRequest(Context)
                Exit Sub
            End If

            'Preparo la stringa col percorso reale
            Dim newPath As String = myDirectory & myRequestPath.Substring(myDirectory.Length)
            newPath = newPath.Substring(0, newPath.LastIndexOf("."))

            'Reindirizzo la richiesta sul server giusto
            Context.Response.Redirect(Settings.GetActiveServer().ServerURL & newPath)
        End Sub

        Public ReadOnly Property IsReusable() As Boolean Implements System.Web.IHttpHandler.IsReusable
            Get
                Return True
            End Get
        End Property

    End Class

    Public Class RemoteServerInfo
        Private _ServerHost As String
        Public ReadOnly Property ServerHost() As String
            Get
                Return _ServerHost
            End Get
        End Property

        Private _ServerURL As String
        Public ReadOnly Property ServerURL() As String
            Get
                Return _ServerURL
            End Get
        End Property

        Public Sub New(ByVal ServerHost As String, ByVal ServerURL As String)
            _ServerHost = ServerHost
            _ServerURL = ServerURL
        End Sub
    End Class

    Public Class BandwidthSettings

        Public ReadOnly Property Servers() As RemoteServerInfo()
            Get
                Return _Servers
            End Get
        End Property

        Public ReadOnly Property DefaultServer() As RemoteServerInfo
            Get
                Return _DefaultServer
            End Get
        End Property

        Public ReadOnly Property Directories() As String()
            Get
                Return _Directories
            End Get
        End Property

        Public ReadOnly Property MissingPageURL() As String
            Get
                Return _MissingPageURL
            End Get
        End Property

        Public ReadOnly Property ServerCheckClass() As String
            Get
                Return _ServerCheckClass
            End Get
        End Property

        Private _ServerCheckClass As String
        Private _Servers As RemoteServerInfo()
        Private _Directories As String()
        Private _MissingPageURL As String
        Private _DefaultServer As RemoteServerInfo

        Public Sub New()
            'Caricamento delle varie impostazioni dal file di configurazione
            Dim myServerNumberString As String = ConfigurationManager.AppSettings("ManualBandwidthManagement_ServerNumber")
            If IsNumeric(myServerNumberString) Then
                ReDim _Servers(myServerNumberString - 1)
            Else
                ReDim _Servers(0)
            End If

            For i As Integer = 1 To _Servers.Length
                Dim tmpItem1, tmpItem2 As String
                tmpItem1 = ConfigurationManager.AppSettings("ManualBandwidthManagement_ServerHost_" & i)
                tmpItem2 = ConfigurationManager.AppSettings("ManualBandwidthManagement_ServerURL_" & i)
                If Not tmpItem1 Is Nothing AndAlso tmpItem1.Length > 0 AndAlso Not tmpItem2 Is Nothing AndAlso tmpItem2.Length > 0 Then
                    _Servers(i - 1) = New RemoteServerInfo(tmpItem1.Trim.ToLower, tmpItem2)
                Else
                    _Servers(i - 1) = New RemoteServerInfo("", "")
                End If
            Next

            Dim myDirectoryNumberString As String = ConfigurationManager.AppSettings("ManualBandwidthManagement_DirectoryNumber")
            If IsNumeric(myDirectoryNumberString) Then
                ReDim _Directories(myDirectoryNumberString - 1)
            Else
                ReDim _Directories(0)
            End If

            For i As Integer = 1 To _Directories.Length
                Dim tmpItem As String
                tmpItem = ConfigurationManager.AppSettings("ManualBandwidthManagement_Directory_" & i)
                If Not tmpItem Is Nothing AndAlso tmpItem.Length > 0 Then
                    _Directories(i - 1) = tmpItem
                Else
                    _Directories(i - 1) = "/"
                End If
            Next

            _MissingPageURL = ConfigurationManager.AppSettings("ManualBandwidthManagement_MissingPageURL")
            If _MissingPageURL Is Nothing Then _MissingPageURL = "/"

            Dim myDefaultServerHost As String = ConfigurationManager.AppSettings("ManualBandwidthManagement_DefaultServerHost")
            Dim myDefaultServerURL As String = ConfigurationManager.AppSettings("ManualBandwidthManagement_DefaultServerURL")
            If myDefaultServerHost Is Nothing Then myDefaultServerHost = ""
            If myDefaultServerURL Is Nothing Then myDefaultServerURL = ""

            _DefaultServer = New RemoteServerInfo(myDefaultServerHost, myDefaultServerURL)

            _ServerCheckClass = ConfigurationManager.AppSettings("ManualBandwidthManagement_ServerCheckClass")
            If _ServerCheckClass Is Nothing Then _ServerCheckClass = "UseDefaultServer"

        End Sub

        Public Function GetDirectory(ByVal RequestPath As String) As String
            If RequestPath Is Nothing Then Return Nothing

            'Verifico se la directory della richiesta è una sottodirectory di un percorso protetto, e in questo caso restituisco i parametri di configurazione 
            For i As Integer = 0 To Directories.Length - 1
                If RequestPath.Substring(0, Directories(i).Length) = Directories(i) Then Return Directories(i)
            Next

            Return Nothing
        End Function

        Public Function GetActiveServer() As RemoteServerInfo

            'Per semplificare il codice e permettere di inserire facilmente nuove modalità di controllo uso la reflection e un'interfaccia
            Dim myTestingModule As IServerTestingModule
            myTestingModule = Assembly.GetExecutingAssembly.CreateInstance(Me.GetType.FullName & "+" & _ServerCheckClass)
            If myTestingModule Is Nothing Then Return _DefaultServer

            Return myTestingModule.GetActiveServer(_Servers, _DefaultServer)
        End Function

        Private Interface IServerTestingModule
            Function GetActiveServer(ByVal ServerList As RemoteServerInfo(), ByVal DefaultServer As RemoteServerInfo) As RemoteServerInfo
        End Interface

        'Di seguito sono riportate 3 classi di esempio da utilizzare per la selezione del server
        'Per utilizzare altre modalità è necessario:
        '- creare di seguito una classe che implementa l'interfaccia IServerTestingModule
        '- inserire il nome della classe come valore di ManualBandwidthManagement_ServerCheckClass del web.config

        Private Class UseDefaultServer
            Implements IServerTestingModule
            'Questa classe seleziona sempre il server predefinito

            Public Function GetActiveServer(ByVal ServerList As RemoteServerInfo(), ByVal DefaultServer As RemoteServerInfo) As RemoteServerInfo Implements IServerTestingModule.GetActiveServer
                Return DefaultServer
            End Function
        End Class

        Private Class SequentialAccess
            Implements IServerTestingModule
            'Questa classe si occupa di selezionare i server in modo sequenziale

            Private Shared _ServerNumber As Integer

            Public Function GetActiveServer(ByVal ServerList As RemoteServerInfo(), ByVal DefaultServer As RemoteServerInfo) As RemoteServerInfo Implements IServerTestingModule.GetActiveServer
                If ServerList.Length = 0 Then Return DefaultServer

                Dim ServerResult As RemoteServerInfo

                If _ServerNumber >= ServerList.Length Then _ServerNumber = 0

                ServerResult = ServerList(_ServerNumber)

                _ServerNumber += 1

                Return ServerResult
            End Function
        End Class

        Private Class FirstAvailable
            Implements IServerTestingModule
            'Questa classe si occupa di verificare la risposta del server al ping
            'Viene selezionato il primo server che risponde al ping nel tempo previsto

            Public Function GetActiveServer(ByVal ServerList As RemoteServerInfo(), ByVal DefaultServer As RemoteServerInfo) As RemoteServerInfo Implements IServerTestingModule.GetActiveServer

                For i As Integer = 0 To ServerList.Length - 1
                    If My.Computer.Network.Ping(ServerList(i).ServerHost, 500) Then
                        Return ServerList(i)
                    End If
                Next

                Return DefaultServer
            End Function
        End Class

    End Class

End Namespace

<?xml version="1.0"?>
<configuration>
    <appSettings>
        <add key="ManualBandwidthManagement_DefaultServerHost" value="hostname_server_predefinito"></add>
        <add key="ManualBandwidthManagement_DefaultServerURL" value="http://www.serverpredefinito.ext"></add>
        <add key="ManualBandwidthManagement_ServerNumber" value="3"></add>
        <add key="ManualBandwidthManagement_ServerHost_1" value="hostname_primo_server"></add>
        <add key="ManualBandwidthManagement_ServerURL_1" value="http://www.primo_server.ext"></add>
        <add key="ManualBandwidthManagement_ServerHost_2" value="hostname_secondo_server"></add>
        <add key="ManualBandwidthManagement_ServerURL_2" value="http://www.secondo_server.ext"></add>
        <add key="ManualBandwidthManagement_ServerHost_3" value="hostname_terzo_server"></add>
        <add key="ManualBandwidthManagement_ServerURL_3" value="http://www.terzo_server.ext"></add>
        <add key="ManualBandwidthManagement_DirectoryNumber" value="2"></add>
        <add key="ManualBandwidthManagement_Directory_1" value="/downloads1/"></add>
        <add key="ManualBandwidthManagement_Directory_2" value="/downloads2/"></add>
        <add key="ManualBandwidthManagement_MissingPageURL" value="http://www.sitoprincipale.ext/pagina404.htm"></add>
        <add key="ManualBandwidthManagement_ServerCheckClass" value="FirstAvailable"/>
    </appSettings>

    <system.web>
        <httpHandlers>
                  <add verb="GET" path="*.zip.aspx" type="GiDiNet.ManualBandwidthManagement"></add>
        </httpHandlers>
    </system.web>
</configuration>